globals [ tempo energia particulas cor ]
breed [ ocupados ocupado ]
breed [ livres livre ]
patches-own [ ligacoes ]

to preparar
    locals [ patches-ocupados ]
    ct cp
    set-current-plot "EM"
    clear-plot
    set tempo 0
    set particulas (count patches) * densidade / 100
    ask patches [ 
        set pcolor white
        sprout-livres 1 [ ht ]
    ]
    if estado-inicial = "aleatorio" [ prepara-aleatorio ] 
    if estado-inicial = "gota" [ prepara-gota ]
    if estado-inicial = "interface" [ prepara-interface ]
    ask patches [ set ligacoes count neighbors4 with [ pcolor = black ] ]
    set patches-ocupados patches-from ocupados [ patch-here ]
    set energia sum values-from patches-ocupados [ligacoes] / (-2 * particulas)
    display
    preparar-grafico
    grafico
end

to prepara-aleatorio
    ask patches [
        if random-float 100 < densidade [ 
            set pcolor black
            ask turtles-here [ set breed ocupados ]
        ]
    ]
end

to prepara-gota
    locals [ lado ]
    set lado int ((sqrt particulas - 1) / 2)
    ask patches with [ abs pxcor <= lado and abs pycor <= lado ][
        set pcolor black
        ask turtles-here [ set breed ocupados ]
    ]
    ask n-of (particulas - (2 * lado + 1) ^ 2) patches with [ 
        (abs pxcor = lado + 1 and abs pycor <= lado + 1) or 
        (abs pxcor <= lado + 1 and abs pycor = lado + 1)
    ][ 
        set pcolor black
        ask turtles-here [ set breed ocupados ]
    ] 
end

to prepara-interface
    locals [ altura ]
    set altura int (particulas / world-width)
    ask patches with [ pycor < altura + min-pycor ] [ set pcolor black ]
    ask n-of (particulas - altura * world-width) patches with [
        pycor = altura + min-pycor
    ][ 
        set pcolor black 
        ask turtles-here [ set breed ocupados ]
    ]
end

to executar
    locals [ ocupado1 livre1 patches-ocupados ]
    no-display
    set ocupado1 one-of ocupados
    set livre1 one-of livres
    Trocar ocupado1 livre1
    every 0.1 [ 
        display
        set patches-ocupados patches-from ocupados [ patch-here ]
        set energia sum values-from patches-ocupados [ligacoes] / (-2 * particulas)
        grafico
    ]
end

to Trocar [ ocupado1 livre1 ]
    locals [ diferenca ]
    set diferenca ligacoes-of livre1 - ligacoes-of ocupado1
    if random-float 1.0 < exp (diferenca / temperatura) [ 
        ask livre1 [ 
            ask neighbors4 [ set ligacoes ligacoes + 1 ] 
            ask patch-here [ set pcolor black ]
            set breed ocupados
        ]
        ask ocupado1 [ 
            ask neighbors4 [ set ligacoes ligacoes - 1 ] 
            ask patch-here [ set pcolor white ]
            set breed livres
        ] 
    ]
    set tempo tempo + 1
end

to preparar-grafico
    set-current-plot "EM"
    set-current-plot-pen "eixo"
    auto-plot-off
    plotxy 0 -2
    plotxy 100000000 -2
    auto-plot-on
end


to grafico
    set-current-plot "EM"
    set-current-plot-pen "epp"
    plotxy tempo energia
end

to temperatura_automatica
    set estado-inicial "gota"
    set-current-plot "energia / temperatura"
    set-plot-pen-color blue
    ppu
    plotxy .55 -.5
    ppd
    plotxy .55 -2
    if cor = 0 [ set cor 5 ]
    set-plot-pen-color cor
    set temperatura 0.45
    while [ temperatura < 0.65 ][
        preparar
        calcula-energia-media
        set-current-plot "energia / temperatura"
        if temperatura = .45 [
            ppu
            plotxy temperatura energia
            ppd
        ]
        plotxy temperatura energia
        set temperatura temperatura + .01
    ]
    set cor cor + 10
end

to densidade_automatica
    set estado-inicial "gota"
    set-current-plot "energia / densidade"
    clear-plot
    set densidade 1
    while [ densidade < 100 ][
        preparar
        calcula-energia-media
        set-current-plot "energia / densidade"
        plotxy densidade energia
        set densidade densidade + 1
    ]
end

to calcula-energia-media
    locals [ lista]
    set lista []
    while [ length lista < 50 ][
        executar
        every 0.1 [ 
            display 
            ifelse length lista < 30 [
                set lista lput energia lista
            ][
                ifelse (energia > sum lista / 30) and (length lista = 30) [
                    set lista but-first lista
                    set lista lput energia lista    
                ][
                    set lista lput energia lista
                ]
            ]
        ]      
    ]
    set lista sublist lista 30 49
    set energia sum lista / 20
end

; Versão Prisma Copyright 2007, Centro de Física Teórica e Computacional
@#$#@#$#@
GRAPHICS-WINDOW
314
10
576
293
31
31
4.0
1
10
1
1
1
0
1
1
1
-31
31
-31
31

CC-WINDOW
5
430
585
525
Command Center
0

SLIDER
1
62
212
95
densidade
densidade
1
99
10
1
1
%

SLIDER
1
101
212
134
temperatura
temperatura
0.01
2.01
0.65
0.01
1
NIL

PLOT
1
142
310
293
EM
tempo
energia por particula
0.0
100.0
-2.1
0.0
true
false
PENS
"eixo" 1.0 0 -13345367 true
"epp" 1.0 0 -16777216 true

MONITOR
224
74
304
123
energia media
energia
3
1

CHOOSER
1
10
118
55
estado-inicial
estado-inicial
"aleatorio" "gota" "interface"
1

BUTTON
124
10
211
55
NIL
preparar
NIL
1
T
OBSERVER
T
NIL

BUTTON
216
10
310
55
NIL
executar
T
1
T
OBSERVER
T
NIL

PLOT
376
296
576
416
energia / temperatura
temperatura
energia
0.45
0.65
-2.0
-0.5
true
false

BUTTON
1
337
169
374
NIL
temperatura_automatica
NIL
1
T
OBSERVER
T
NIL

BUTTON
1
296
169
333
NIL
densidade_automatica
NIL
1
T
OBSERVER
T
NIL

PLOT
173
296
373
416
energia / densidade
densidade
energia
0.0
100.0
-2.0
0.0
true
false

BUTTON
1
378
169
415
limpar
ca
NIL
1
T
OBSERVER
T
NIL

@#$#@#$#@
Introdução
-----------
Este programa utiliza um modelo chamado gás de rede (ou "lattice gas") para demonstrar algumas características da transição de fase líquido vapor. 
As partículas da substância são representadas por sítios (patches) ocupados e pretos. É possível variar a quantidade de partículas (ou densidade, número de partículas por unidade de área) e a temperatura do sistema de forma independente. Em consequência este programa vai permitir investigar o diagrama de fases densidade-temperatura do gás de rede que possui as mesmas características do diagrama de fases das substâncias simples correspondente às fases líquido e vapor.
 
Utilização
-----------
O objectivo deste programa é descobrir as configurações de equilíbrio (e a energia correspondente) do gás de rede para um par de parâmetros (densidade, temperatura). 
Os agentes deste programa são apenas "patches" de dois tipos, ocupados (pretos) e desocupados (brancos). Cada par de patches vizinhos ocupados tem energia -1 e, consequentemente, a energia de uma configuração é igual ao simétrico do número de pares de patches vizinhos ocupados. Na versão aqui apresentada, cada ?patch? tem 4 vizinhos (os sítios da rede mais próximos).
Depois de gerada uma configuração inicial, o programa procura as configurações de equilíbrio tentando movimentar partículas para sítios desocupados; i.e., tentando trocar patches ocupados com patches desocupados. Em cada iteração, são escolhidos aleatóriamente dois patches, um ocupado e outro desocupado. Para decidir se efectua ou não esta troca, o programa calcula a diferença de energia (DE) entre a configuração que resultaria da troca e a actual. Se esta diferença de energia for negativa (i.e. se da troca resultar uma diminuição da energia) então a nova configuração é aceite; se a diferença de energia for positiva a troca é efectuada com probabilidade p = exp(-DE/T).
Ao longo do seu funcionamento, o programa regista a energia média do sistema por partícula (ou seja, o número de pares de patches vizinhos ocupados dividido pelo número de patches ocupados).
O programa apresenta dois sliders: a densidade ou fracção de patches ocupados (em percentagem) e a temperatura.
Estes dois parâmetros podem ser variados de forma independente. No início da utilização deste programa devem escolher-se os valores destes parâmetros. 
O estabelecimento da configuração inicial é feito utilizando um dos três botões de preparar. 
Todos vão ?criar? um número de patches ocupados proporcional à densidade: o Preparar Aleatório; distribui aleatóriamente esses patches sobre a rede;
o Preparar Gota; coloca esses patches num aglomerado no centro da rede. 
o Preparar Interface; coloca esses patches num aglomerado na parte inferior da rede
O botão executar faz ?arrancar? o programa, i.e., inicia a procura das configurações de equilíbrio tentando trocar patches ocupados e desocupados de posição
O ?monitor? Energia Média; representa a energia do sistema por partícula para a configuração ilustrada.
Existe um ?plot? que representa em gráfico a energia por partícula em função do número de iterações. 
Em resumo, para usar este programa dão-se os seguintes passos:
-definição dos valores da densidade e da temperatura usando os respectivos ?sliders?;
-escolha do tipo de condições iniciais (aleatórias, aglomerado ou interface)
-observação, no plot e na janela gráfica, da evolução do sistema em direcção ao estado de equilíbrio.
-os estados de equilíbrio são atingidos quando a energia começa a apresentar apenas pequenas oscilações em torno de um valor médio
-para ?parar? o programa pode carregar no botão «executar» ou escolher no menu principal as opções ?tools ? halt?.

Note que existe uma ligeira diferença técnica entre os dois ?sliders?: a temperatura pode ser variada enquanto o programa corre, não se passando o mesmo com a densidade.

 
Questões
---------
1) Fixe a temperatura em 0.30 e a densidade em 10%. Corra o programa durante algum tempo para cada condição inicial, deixando a energia convergir para um valor estável. Observe a janela de representação gráfica das configurações, que deve ter o seguinte aspecto ( utilize screen-edge x e y =40, patch size=1 e font size=1).

NOTA: Deveria ser obtida uma única gota quando se utiliza o setup.No entanto, analisando os resultados é possível observar a formação de várias gotas. Seria necessário esperar mais tempo para que essas gotas se juntassem numa só.Nesta situação existe coexistência líquido vapor: o estado líquido corresponde à gota compacta de patches pretos; o estado gasoso aos patches pretos isolados. 

2) Para a mesma densidade aumente a temperatura para 0.75. Verifique que neste caso não existe coexistência líquido vapor.Interprete os resultados obtidos em 1) e 2) em termos de minimização da energia e maximização da entropia.

3) Repita os procedimentos de 1) para as densidades: 30%, 50% e 70%. Relacione os resultados obtidos com o diagrama de fases do gás de rede.

4) Fixe uma densidade e uma temperatura. Compare a evolução da energia com as iterações para as duas escolhas de condições iniciais(setup e setup-drop).Em qual das situações converge a energia mais rapidamente para o valor de equilíbrio?Porquê?

5) A energia (por partícula) pode variar entre -2 e 0. Tente escolher pares densidade/temperatura em que, na situação de equilíbrio, a energia se aproxime destes valores.

6) Percorra o diagrama de fases de forma sistemática a uma densidade constante (< 50%). Registe, para cada temperatura, o valor da energia no equilíbrio.

7)Repita a questão 5 para os diferentes tipos de setup, confronte os resultados e veja o que pode concluir

8)Fixe a densidade a 50% e percorra a temperatura (começe em 0.35) em passos de 0.05

Extensões e variantes
---------------------
 
- Para verificar de forma visual que a quantidade de trocas de configuração aceites é muito maior quando a temperatura aumenta, pode "pintar" de uma terceira cor os "patches" ocupados que resultaram da troca com um patch desocupado.

- Construa um "reporter" que registe o número de pares de patches vizinhos ocupado-desocupado (por patch ocupado). Verifique se este parâmetro adicional pode ajudar à identificação da fase em que se encontra o sistema.

- Altere o programa de modo a que os patches vizinhos sejam oito (os quatro mais próximos da actual versão + os 4 seguintes em proximidade). Verifique que a única alteração relevante é a variação da temperatura crítica. 

- Acrescente ao programa um campo gravítico, i.e., considere que a energia das partículas depende da sua altura (é tanto mais elevada quanto maior for a altura). Utilize um slider para poder controlar a intensidade deste campo e altere convenientemente o cálculo da diferença de energias entre configurações.iniciais. 

Quais as principais alterações verificadas nos estados de equilíbrio a temperaturas elevadas e a temperaturas baixas?


 analisando a evolução da estrutura do sistema. Verifique que à volta de T= 0.55 a estrutura é diferente da observada a temperaturas mais baixas e mais altas
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

link
true
0
Line -7500403 true 150 0 150 300

link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

ant
true
0
Polygon -7500403 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7500403 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7500403 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186
Polygon -7500403 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7500403 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7500403 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7500403 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7500403 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7500403 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -1184463 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7500403 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7500403 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7500403 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6459832 true false 150 32 157 162
Polygon -13345367 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7500403 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7500403 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6459832 true false 150 32 157 162
Polygon -13345367 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7500403 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7500403 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6459832 true false 150 32 157 162
Polygon -13345367 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7500403 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7500403 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7500403 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7500403 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7500403 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7500403 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7500403 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7500403 true 167 47 159 82
Line -7500403 true 136 47 145 81
Circle -7500403 true true 165 45 8
Circle -7500403 true true 134 45 6
Circle -7500403 true true 133 44 7
Circle -7500403 true true 133 43 8

circle
false
0
Circle -7500403 true true 35 35 230

person
false
0
Circle -7500403 true true 155 20 63
Rectangle -7500403 true true 158 79 217 164
Polygon -7500403 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7500403 true true 216 83 267 123 248 143 215 107
Polygon -7500403 true true 167 163 145 234 183 234 183 163
Polygon -7500403 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

spacecraft
true
0
Polygon -7500403 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7500403 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7500403 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8630108 true false 195 75 195 120 240 120 240 75
Polygon -8630108 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7500403 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8630108 true false 90 210 105 225 120 210
Polygon -8630108 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7500403 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8630108 true false 210 210 195 225 180 210
Polygon -8630108 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7500403 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf
false
0
Rectangle -7500403 true true 15 105 105 165
Rectangle -7500403 true true 45 90 105 105
Polygon -7500403 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7500403 true true 105 120 263 195
Rectangle -7500403 true true 108 195 259 201
Rectangle -7500403 true true 114 201 252 210
Rectangle -7500403 true true 120 210 243 214
Rectangle -7500403 true true 115 114 255 120
Rectangle -7500403 true true 128 108 248 114
Rectangle -7500403 true true 150 105 225 108
Rectangle -7500403 true true 132 214 155 270
Rectangle -7500403 true true 110 260 132 270
Rectangle -7500403 true true 210 214 232 270
Rectangle -7500403 true true 189 260 210 270
Line -7500403 true 263 127 281 155
Line -7500403 true 281 155 281 192

wolf-left
false
3
Polygon -6459832 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6459832 true true 87 80 79 55 76 79
Polygon -6459832 true true 81 75 70 58 73 82
Polygon -6459832 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6459832 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6459832 true true 116 140 114 189 105 137
Rectangle -6459832 true true 109 150 114 192
Rectangle -6459832 true true 111 143 116 191
Polygon -6459832 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6459832 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6459832 true true 214 134 203 168 192 148
Polygon -6459832 true true 204 151 203 176 193 148
Polygon -6459832 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6459832 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6459832 true true 201 99 214 69 215 99
Polygon -6459832 true true 207 98 223 71 220 101
Polygon -6459832 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6459832 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6459832 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6459832 true true 48 143 58 141
Polygon -6459832 true true 46 136 68 137
Polygon -6459832 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6459832 true true 38 138 66 149
Polygon -6459832 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6459832 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 3.1.3
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@