Infiltração de Óleo em Solos Porosos

porosidade de 65.4% (agregado fractal)

Breve Análise do Código

A análise do código referente a este programa foi efectuada com detalhe no capítulo introdutório. Nesta secção, serão feitas referências a ligeiras modificações que foram introduzidas.

Analisando a primeira função que aparece no programa, e comparando com a mesma função que aparece no capitulo introdutório é possível verificar a existência da introdução de novas linhas de código.Vejamos então:

to preparar
  ca
  set oleo-total 0
  ask patches [
    set pcolor brown           ;; óleo não saturado    
    if (pxcor = screen-edge-x)     
      [ set pcolor yellow ]    ;; coloca fronteira no lado direito do ecrã
                               ;; previne que óleo salte a fronteira
  ]
  set linha patches with [pycor = screen-edge-y]
  ask linha [
    if (pxcor mod 2 = 0) and (pcolor != yellow)
      [ set pcolor red ]                        ;; inicializa uma linha de óleo
                                                ;; representada por patches vermelhos
  ]
  do-plot
end

De modo a tornar o modelo mais realista foi necessário introduzir uma condição de fronteira (lateral) que não permitisse ao óleo saltar para fora do terreno, o que foi conseguido introduzindo as seguintes linhas de código na função preparar

if (pxcor = screen-edge-x) pinta uma linha de amarelo no lado direito do ecrã
[ set pcolor yellow ]

Foi também necessário simular o óleo derramado no terreno e que vai percolar no decorrer da simulação, por uma linha vermelha que se encontra na parte superior da caixa. Para isso, foi introduzida na função preparar o seguinte conjunto de instruções:

set linha patches with [pycor = screen-edge-y] ;; define uma linha de patches cuja a coordenada é screen-edge-y(linha superior da janela da interface)
ask linha [ ;; chama a linha de patches que foi previamente defenida
if (pxcor mod 2 = 0) and (pcolor != yellow) ;; para essa linha e excluindo os patches cuja coordenada é impar e todos os de cor amarela
[ set pcolor red ] ;; pinta os restantes da cor vermelha

Analisando a seguinte função

to executar
  if not any? linha with [pcolor = red]
    [ stop ]
  percolar
  do-plot
  verificar
end

e confrontando com o que foi explicado na introdução é possível verificar uma ligeira diferença. Na introdução, verificou-se a cor de cada patch individualmente enquanto que aqui, essa verificação é feita linha a linha, ou seja, para cada linha verifica-se se existem patches vermelhos. Se não existirem a simulação termina e se existirem a simulação continua com as funções percolar e verificar

to percolar
  ask linha with [pcolor = red] [
                           ;; óleo percola para os dois patches a sudeste e sudoeste
    ask patches at-points [[-1 -1] [1 -1]]
      [ if (pcolor = brown) and (random-float 100 < porosidade)
          [ set pcolor red ] ]
    set pcolor black
    set oleo-total oleo-total + 1
  ]
  set linha patches-from linha [patch-at 0 -1]
end

to verificar         ;; caso óleo atinja margem inferior do ecrã este é apagado
                                             ;; e simulação continua no topo
  if pycor-of one-of linha = screen-edge-y
    [ 
      display
      ask patches with [pcolor = black]
        [ set pcolor brown ] ]
end

Estas duas funções são práticamente iguais ás funções percolar e executar apresentadas na introdução

Por último temos a função que nos permite obter os gráficos

to do-plot
  set-current-plot "Óleo Percolado"
  plot count linha with [pcolor = red]
  set-current-plot "Terra Contaminada"
  plot oleo-total
end

Variantes e Extensões

Adicione um slider que permita controlar a quantidade de óleo derramada e use este parâmetro para prever a profundidade a que uma determinada quantidade de óleo pode chegar, para um dado tipo de solo. Repita as simulações para tipos de solos diferentes.

Torne o modelo mais realista fazendo a porosidade depender da profundidade do solo. Repita as simulações. Observa algumas diferenças relativamente ao modelo original ?

Use a largura da caixa de simulação como um parâmetro adicional e verifique a dependência do fluxo nesta quantidade.

©opyright 2004, Centro de Física Teórica e Computacional
O programa utilizado foi implementado pela Northwestern University, Evanston, IL.